Skocz do zawartości

Zablokowane VIP

Mdks

Przez   Mdks
w Tematy Archiwalne

 Udostępnij

Rekomendowane odpowiedzi

Mdks Nowy

  Mdks

Napisano
Napisano

Szukam pluginu dla vipa. Vip ma posiadać:

 

  • pervix prze nickiem 
  • pervix w tabeli wyników 
  • kevlar + hełm 
  • powitanie gdy wchodzisz na serwer 
  • deagl 
  • za zabicie z HS +10hp | za zwykłego fraga +5hp max. 130hp
  • auto BH

  Za pomoc daje "+" i szacunek  :D

 

Odnośnik do komentarza
https://csowicze.pl/topic/35195-vip/
Udostępnij na innych stronach
Gość esej

Gość esej

Napisano
Napisano

A vipmdks.amxx i vipmdks.sma nie jest potrzebny?

Jeżeli chcesz edytować to byłby ci potrzebny (jak nie to wystarczy ci plik amxx) mogę dać ci tutaj kod .SMA + dodaje poprawionego vipa bo tam popełniłem błąd

#include <amxmodx>
#include <cstrike>
#include <engine>
#include <fun>
#include <hamsandwich>

#define FL_ONGROUND (1<<9)
#define FL_WATERJUMP (1<<11)
#define g_Buffer 1536

forward amxbans_admin_connect(id);

new Array:g_Array, bool:g_Vip[33], g_Hudmsg, weapon_id;

new const g_Langcmd[][]={"say /vips","say_team /vips","say /vipy","say_team /vipy"};

public plugin_init(){
	register_plugin("VIP Ultimate", "12.3.0.2", "benio101 & speedkill");
	RegisterHam(Ham_Spawn, "player", "SpawnedEventPre", 1);
	register_event("DeathMsg", "DeathMsg", "a");
	register_message(get_user_msgid("ScoreAttrib"), "VipStatus");
	g_Array=ArrayCreate(64,32);
	for(new i;i<sizeof g_Langcmd;i++){
		register_clcmd(g_Langcmd[i], "ShowVips");
	}
	register_clcmd("say /vip", "ShowMotd");
	register_message(get_user_msgid("SayText"),"handleSayText");
	g_Hudmsg=CreateHudSyncObj();
}
public client_authorized(id){
	if(get_user_flags(id) & 524288 == 524288){
		client_authorized_vip(id);
	}
}
public client_authorized_vip(id){
	g_Vip[id]=true;
	new g_Name[64];
	get_user_name(id,g_Name,charsmax(g_Name));
	
	new g_Size = ArraySize(g_Array);
	new szName[64];
	
	for(new i = 0; i < g_Size; i++){
		ArrayGetString(g_Array, i, szName, charsmax(szName));
		
		if(equal(g_Name, szName)){
			return 0;
		}
	}
	ArrayPushString(g_Array,g_Name);
	set_hudmessage(24, 190, 220, 0.25, 0.2, 0, 6.0, 6.0);
	ShowSyncHudMsg(0, g_Hudmsg, "Vip %s wbija na serwer!",g_Name);
	
	return PLUGIN_CONTINUE;
}
public client_disconnect(id){
	if(g_Vip[id]){
		client_disconnect_vip(id);
	}
}
public client_disconnect_vip(id){
	g_Vip[id]=false;
	new Name[64];
	get_user_name(id,Name,charsmax(Name));
	
	new g_Size = ArraySize(g_Array);
	new g_Name[64];
	
	for(new i = 0; i < g_Size; i++){
		ArrayGetString(g_Array, i, g_Name, charsmax(g_Name));
		
		if(equal(g_Name,Name)){
			ArrayDeleteItem(g_Array,i);
			break;
		}
	}
}
public SpawnedEventPre(id){
	if(g_Vip[id]){
		if(is_user_alive(id)){
			SpawnedEventPreVip(id);
		}
	}
}
public SpawnedEventPreVip(id){
	give_item(id, "weapon_deagle");
	give_item(id, "ammo_50ae");
	weapon_id=find_ent_by_owner(-1, "weapon_deagle", id);
	if(weapon_id)cs_set_weapon_ammo(weapon_id, 7);
	cs_set_user_bpammo(id, CSW_DEAGLE, 35);
	new g_Model[64];
	formatex(g_Model,charsmax(g_Model),"%s",get_user_team(id) == 1 ? "VipTT" : "VipCT");
	cs_set_user_model(id,g_Model);
	if(get_user_team(id)==2){
		give_item(id, "item_thighpack");
	}
}
public DeathMsg(){
	new killer=read_data(1);
	new victim=read_data(2);
	
	if(is_user_alive(killer) && g_Vip[killer] && get_user_team(killer) != get_user_team(victim)){
		DeathMsgVip(killer,victim,read_data(3));
	}
}
public DeathMsgVip(kid,vid,hs){
	set_user_health(kid, min(get_user_health(kid)+(hs?10:5),130));
}
public VipStatus(){
	new id=get_msg_arg_int(1);
	if(is_user_alive(id) && g_Vip[id]){
		set_msg_arg_int(2, ARG_BYTE, get_msg_arg_int(2)|4);
	}
}
public ShowVips(id){
	ShowVipsMotd(id);
	return PLUGIN_CONTINUE;
}
public ShowVipsMotd(id){
	new Data[g_Buffer],Len,g_Name[64];
	
	Len = formatex(Data[Len], g_Buffer - Len, "<html><body bgcolor=Black><br>");
	Len += formatex(Data[Len], g_Buffer - Len, "<center><table frame=^"border^" width=^"600^" cellspacing=^"0^" bordercolor=#4A4344 style=^"color:#56A5EC;text-align:center;^">");
	Len += formatex(Data[Len], g_Buffer- Len, "<tr><td><b>#</b></td><td><b>Nick</b></td></td></tr>");
	
	new g_Size=ArraySize(g_Array);
	
	for(new i = 0; i < g_Size; i++){
		ArrayGetString(g_Array, i, g_Name, charsmax(g_Name));
		
		Len += formatex(Data[Len], g_Buffer - Len, "<tr>");
		Len += formatex(Data[Len], g_Buffer - Len, "<td><font color=Red>%d</font></td>", i + 1);
		Len += formatex(Data[Len], g_Buffer - Len, "<td>%s</td>", g_Name);
		Len += formatex(Data[Len], g_Buffer - Len, "</tr>");
	}
	Len += formatex(Data[Len],g_Buffer - Len,"</center></body></html>");
	
	show_motd(id, Data, "Vipy Online");
}
public client_infochanged(id){
	if(g_Vip[id]){
		new szName[64];
		get_user_info(id,"name",szName,charsmax(szName));
		
		new Name[64];
		get_user_name(id,Name,charsmax(Name));
		
		if(!equal(szName,Name)){
			ArrayPushString(g_Array,szName);
			
			new g_Size=ArraySize(g_Array);
			new g_Name[64];
			for(new i = 0; i < g_Size; i++){
				ArrayGetString(g_Array, i, g_Name, charsmax(g_Name));
				
				if(equal(g_Name,Name)){
					ArrayDeleteItem(g_Array,i);
					break;
				}
			}
		}
	}
}
public plugin_end(){
	ArrayDestroy(g_Array);
}
public ShowMotd(id){
	show_motd(id, "vip.txt", "Informacje o vipie");
}
public handleSayText(msgId,msgDest,msgEnt){
	new id = get_msg_arg_int(1);
	
	if(is_user_connected(id) && g_Vip[id]){
		new szTmp[256],szTmp2[256];
		get_msg_arg_string(2,szTmp, charsmax(szTmp))
		
		new szPrefix[64] = "^x04[VIP]";
		
		if(!equal(szTmp,"#Cstrike_Chat_All")){
			add(szTmp2,charsmax(szTmp2),szPrefix);
			add(szTmp2,charsmax(szTmp2)," ");
			add(szTmp2,charsmax(szTmp2),szTmp);
		}
		else{
			add(szTmp2,charsmax(szTmp2),szPrefix);
			add(szTmp2,charsmax(szTmp2),"^x03 %s1^x01 :  %s2");
		}
		set_msg_arg_string(2,szTmp2);
	}
	return PLUGIN_CONTINUE;
}
public plugin_precache(){
	precache_model("models/player/VipCT/VipCT.mdl");
	precache_model("models/player/VipTT/VipTT.mdl");
}
public client_PreThink(id){
	if(g_Vip[id] && is_user_alive(id)){
		client_PreThinkVip(id);
	}
}
public client_PreThinkVip(id){
	entity_set_float(id, EV_FL_fuser2, 0.0);
	
	if(entity_get_int(id, EV_INT_button) & 2){
		new flags = entity_get_int(id, EV_INT_flags);
		
		if(flags & FL_WATERJUMP || entity_get_int(id, EV_INT_waterlevel) >= 2 || !(flags & FL_ONGROUND)){
			return PLUGIN_CONTINUE;
		}
		new Float:velocity[3];
		entity_get_vector(id, EV_VEC_velocity, velocity);
		
		velocity[2] += 250.0;
		entity_set_vector(id, EV_VEC_velocity, velocity);
		
		entity_set_int(id, EV_INT_gaitsequence, 6);
	}
	return PLUGIN_CONTINUE;
}
public amxbans_admin_connect(id){
	client_authorized(id);
}
Odnośnik do komentarza
https://csowicze.pl/topic/35195-vip/#findComment-163644
Udostępnij na innych stronach
Gość esej

Gość esej

Napisano
Napisano

Działa bo przed chwilką sprawdzałem na serwerze testowym 

 

1) Ściągnij ten plik

http://www71.zippyshare.com/v/A9YcxLIG/file.html

2) Wklej zawartość archiwum do

addons/amxmodx/plugins

3) Znajdz plik plugins.ini który znajduje się

addons/amxmodx/configs

4) Dopisz na końcu 

vipmdks2.amxx      ; vip

Jak chcesz opis VIPa pod komendą /VIP to zrób samodzielnie pliczek ponieważ komenda jest już gotowa  :)

Odnośnik do komentarza
https://csowicze.pl/topic/35195-vip/#findComment-163719
Udostępnij na innych stronach
  • 2 miesiące później...
kuben216 Nowy

kuben216

Napisano
Napisano

Wiadomość wygenerowana automatycznie

 

temat_zamkniety.png
Powód: Problem wyjaśniony.

 

Jeżeli się z tym nie zgadzasz raportuj ten post a moderator lub administrator rozpatrzy go ponownie.
Z pozdrowieniami.
Administracja CSowicze.pl

Odnośnik do komentarza
https://csowicze.pl/topic/35195-vip/#findComment-190108
Udostępnij na innych stronach
  • 11 miesięcy później...
Gość
Ten temat został zamknięty. Brak możliwości dodania odpowiedzi.
 Udostępnij
Przejdź do listy tematów

  • Ostatnio przeglądający   0 użytkowników

    • Brak zarejestrowanych użytkowników przeglądających tę stronę.
×
×
  • Dodaj nową pozycję...

Powiadomienie o plikach cookie

  I accept